***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Mar 05, 2021                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJT7603_P   D   G   S
*****param & model definition***
.model  dmos  pmos(
+    l = 1e-6		   w = 1e-6		level = 3
+  vto = -1.58		  kp = 4.2e-1		)
.model  dds   d(
+   is = 3.106e-13	   n = 1.010		   rs = 5.327e-2
+   eg = 1.018	        trs1 = -1.200e-3)
.model  dbody d(
+   is = 3.106e-13	   n = 1.010	 	   rs = 5.327e-2
+   eg = 1.018	        trs1 = -1.200e-3
+  cjo = 1.665e-11	   m = 1.321e-1		   vj = 3.905e-1
+   bv = 66		 ibv = 250e-6
+ tbv1 = 5.902e-4	tt = 25n)
.model  inter  pmos(
+  vto = 0		  kp = 10		level = 1)
.model  dgd    d(
+  cjo = 1.068e-11	   m = 3.983e-1		   vj = 7.551e-1)
.param
+  cgs = 5.420e-11	 cgd = 1.100e-11
+   rd = 7.532e-1	  ra = 7.837e-1
+ trd1 = 7.022e-3	trd2 = 5.915e-5
*****function & circuit***
rg	  G  1t   1
cgs	 1t   3   {cgs}
egv	  3  2t   table   {v(S, 1t)}
+((0.00 , 0.00 ),
+ (1.00 , 1.10 ),
+ (2.00 , 2.00 ),
+ (3.00 , 3.00 ),
+ (3.50 , 3.48 ),
+ (3.75 , 3.56 ),
+ (4.00 , 3.61 ),
+ (4.25 , 3.66 ),
+ (4.50 , 3.70 ),
+ (6.00 , 3.77 ),
+ (8.00 , 3.81 ),
+ (10.0 , 3.85 ),
+ (20.0 , 3.70 ))
egt	  1  2t   value = {2.3e-4*limit(v(2t,3),-5,0)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd1},{trd2}
dds	  4   3   dds
dbody	  D   3   dbody
ra	  4   2   {ra}
rs	  3   5   1e-4
ls	  5   S   0.001n
m1       1t   8   6   6   inter
e1        8   6   4   1t  2
cgd	  7   4   {cgd}
rcgd      7   4   10meg
dgd       4   6   dgd
rdgd      4   6   10meg
m2        7   9  1t  1t   inter
e2        9  1t   4  1t   -2
.ends
*$
.subckt   PJT7603_N   D   G   S
*****param & model definition***
.model  dmos  nmos(
+    l = 1e-6		   w = 1e-6			level = 3
+  vto = 0.9825		  kp = 0.504		   rb = 9.207e-2)
.model  dds   d(
+   is = 2.105e-12	   n = 1.003		   rs = 1.825e-1		ikf = 8.418e-3
+   eg = 1.080		  trs1 = 1.301e-4)
.model  dbody d(
+   is = 2.105e-12	  n = 1.003		   rs = 1.825e-1		ikf = 8.418e-3
+   eg = 1.050		  trs1 = 1.301e-4
+  cjo = 1.044e-11	   m = 2.314e-1		   vj = 3.380e-1
+   bv = 66		 ibv = 250e-6		 tbv1 = 8.017e-4		tt = 25n)
.model  inter  nmos(
+  vto = 0		  kp = 10		level = 1)
.model  dgd    d(
+  cjo = 1.145e-11	   m = 1.414e-1		   vj = 3.315e-1)
.param
+  cgs = 1.342e-10	 cgd = 4.809e-11
+   rd = 2.260e-1	  ra = 2.221e-1		 trd1 = 2.031e-2
*****function & circuit***
rg	  G  1t   1
cgs	 1t   3   {cgs}
egv	  2t  3   table   {v(1t, S)}
+((0.00 , 0.00 ),
+ (1.00 , 1.00 ),
+ (1.50 , 1.50 ),
+ (1.75 , 1.75 ),
+ (2.00 , 2.00 ),
+ (2.50 , 2.50 ),
+ (3.00 , 2.98 ),
+ (3.50 , 3.12 ),
+ (4.00 , 3.23 ),
+ (4.50 , 3.26 ),
+ (6.00 , 3.30 ),
+ (8.00 , 3.32 ))
+ (10.0 , 3.34 ))
egt	  1  2t   value = {1.387e-3*limit(v(2t,3),0,1.0)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}   tc = {trd1}
dds	  3   4   dds
dbody	  3   D   dbody
ra	  4   2   {ra}
rs	  3   5   1e-4
ls	  5   S   0.001n
m1       1t   8   6   6   inter
e1        8   6   4   1t  2
cgd	  7   4   {cgd}
rcgd      7   4   10meg
dgd       6   4   dgd
rdgd      4   6   10meg
m2        7   9  1t  1t   inter
e2        9  1t   4  1t   -2
.ends
*$
